flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

{
  description = "Swayfx development environment";
  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
  outputs =
    { self, nixpkgs, ... }:
    let
      pkgsFor = system: import nixpkgs { inherit system; };
      targetSystems = [
        "aarch64-linux"
        "x86_64-linux"
      ];
      mkPackage = pkgs: {
        swayfx-unwrapped =
          (pkgs.swayfx-unwrapped.override {
            # When the sway 1.9 rebase is finished, this will need to be overridden.
            # wlroots_0_16 = pkgs.wlroots_0_16;
          }).overrideAttrs
            (old: {
              version = "0.3.2-git";
              src = pkgs.lib.cleanSource ./.;
            });
      };
    in
    {
      overlays = rec {
        default = override;
        # Override onto the input nixpkgs
        override = _: prev: mkPackage prev;
        # Insert using the locked nixpkgs
        insert = _: prev: mkPackage (pkgsFor prev.system);
      };

      packages = nixpkgs.lib.genAttrs targetSystems (
        system: (mkPackage (pkgsFor system) // { default = self.packages.${system}.swayfx-unwrapped; })
      );

      devShells = nixpkgs.lib.genAttrs targetSystems (
        system:
        let
          pkgs = pkgsFor system;
        in
        {
          default = pkgs.mkShell {
            name = "swayfx-shell";
            inputsFrom = [
              self.packages.${system}.swayfx-unwrapped
              pkgs.wlroots_0_16
            ];
            nativeBuildInputs = with pkgs; [
              cmake
              wayland-scanner
            ];
            # Copy the nix version of wlroots into the project
            shellHook = with pkgs; ''
              (
                mkdir -p "$PWD/subprojects" && cd "$PWD/subprojects"
                cp -R --no-preserve=mode,ownership ${wlroots_0_16.src} wlroots
              )'';
          };
        }
      );

      formatter = nixpkgs.lib.genAttrs targetSystems (system: {
        default = (pkgsFor system).nixfmt-rfc-style;
      });
    };
}