blob: 97b61ec62907f35dd335a3923c3c6823ca49cdd0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
{
description = "Scenefx development environment";
inputs.nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
outputs =
{ self, nixpkgs, ... }:
let
mkPackages = pkgs: {
scenefx = pkgs.callPackage (
{ wlroots_0_17, ... }:
pkgs.stdenv.mkDerivation {
pname = "scenefx";
version = "0.1.0-git";
src = ./.;
outputs = [
"out"
"lib"
];
nativeBuildInputs = with pkgs; [
pkg-config
meson
cmake
ninja
scdoc
];
buildInputs = with pkgs; [
libdrm
libxkbcommon
pixman
libGL # egl
mesa # gbm
wayland # wayland-server
wayland-protocols
wlroots_0_17
];
meta = with pkgs.lib; {
description = "A drop-in replacement for the wlroots scene API that allows wayland compositors to render surfaces with eye-candy effects";
homepage = "https://github.com/wlrfx/scenefx";
license = licenses.mit;
platforms = platforms.linux;
};
}
) { };
};
targetSystems = [
"aarch64-linux"
"x86_64-linux"
];
pkgsFor = system: import nixpkgs { inherit system; };
forEachSystem = f: nixpkgs.lib.genAttrs targetSystems (system: f (pkgsFor system));
in
{
overlays = rec {
default = insert;
override = _: prev: mkPackages prev;
insert = _: prev: mkPackages (pkgsFor prev.system);
};
packages = forEachSystem (
pkgs: (mkPackages pkgs) // { default = self.packages.${pkgs.system}.scenefx; }
);
devShells = forEachSystem (pkgs: {
default = pkgs.mkShell {
name = "scenefx-shell";
inputsFrom = [
self.packages.${pkgs.system}.scenefx
pkgs.wlroots_0_17
];
shellHook = ''
(
# Copy the nix version of wlroots into the project
mkdir -p "$PWD/subprojects" && cd "$PWD/subprojects"
cp -R --no-preserve=mode,ownership ${pkgs.wlroots_0_17.src} wlroots
)'';
};
});
formatter = forEachSystem (pkgs: pkgs.nixfmt-rfc-style);
};
}
|
