nix/lua.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

defaults: {
  pkgs ? defaults.pkgs,
  astal ? defaults.astal,
  name ? "astal-lua",
  src,
  extraLuaPackages ? (ps: []),
  extraPacakges ? [],
}: let
  lua = pkgs.lua.withPackages (ps:
    (extraLuaPackages ps)
    ++ [
      ps.lgi
      (ps.luaPackages.toLuaModule (pkgs.stdenv.mkDerivation {
        name = "astal";
        version = "0.1.0";
        src = "${astal}/core/lua";
        dontBuild = true;
        installPhase = ''
          mkdir -p $out/share/lua/${ps.lua.luaversion}/astal
          cp -r astal/* $out/share/lua/${ps.lua.luaversion}/astal
        '';
      }))
    ]);

  nativeBuildInputs = with pkgs; [
    wrapGAppsHook
    gobject-introspection
  ];

  buildInputs =
    extraPacakges
    ++ [
      lua
      astal.packages.${pkgs.system}.default
    ];

  script = pkgs.writeScript "astal-lua" ''
    #!${lua}/bin/lua
    package.path = package.path .. ";${src}/?.lua"
    require "app"
  '';
in
  pkgs.stdenv.mkDerivation {
    inherit nativeBuildInputs buildInputs src name;

    installPhase = ''
      mkdir -p $out/bin
      cp -r * $out/bin
      cp ${script} $out/bin/${name}
      chmod +x $out/bin/${name}
    '';

    preFixup = ''
      gappsWrapperArgs+=(
        --prefix PATH : "${pkgs.lib.makeBinPath extraPacakges}"
      )
    '';
  }