lib/mpris/mpris.vala


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

namespace AstalMpris {
public Mpris get_default() {
    return Mpris.get_default();
}

public class Mpris : Object {
    internal static string PREFIX = "org.mpris.MediaPlayer2.";

    private static Mpris instance;
    public static Mpris get_default() {
        if (instance == null)
            instance = new Mpris();

        return instance;
    }

    private DBusImpl proxy;

    private HashTable<string, Player> _players =
        new HashTable<string, Player> (str_hash, str_equal);

    public List<weak Player> players { owned get { return _players.get_values(); } }

    public signal void player_added (Player player);
    public signal void player_closed (Player player);

    construct {
        try {
            proxy = Bus.get_proxy_sync(
                BusType.SESSION,
                "org.freedesktop.DBus",
                "/org/freedesktop/DBus"
            );

            foreach (var busname in proxy.list_names()) {
                if (busname.has_prefix(Mpris.PREFIX))
                    add_player(busname);
            }

            proxy.name_owner_changed.connect((name, old_owner, new_owner) => {
                if (!name.has_prefix(Mpris.PREFIX))
                    return;

                if (new_owner != "" && old_owner == "")
                    add_player(name);
            });
        } catch (Error error) {
            critical(error.message);
        }
    }

    private void add_player(string busname) {
        var p = new Player(busname);
        _players.set(busname, p);

        p.closed.connect(() => {
            player_closed(p);
            _players.remove(busname);
            notify_property("players");
        });

        player_added(p);
        notify_property("players");
    }
}
}