From eccf0b25987b2b194031edf3415e9f09a7ad7119 Mon Sep 17 00:00:00 2001
From: Drew DeVault <sir@cmpwn.com>
Date: Tue, 27 Mar 2018 13:35:34 -0400
Subject: Add client protocols and swaybg skeleton

---
 protocols/meson.build | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 protocols/meson.build

(limited to 'protocols/meson.build')

diff --git a/protocols/meson.build b/protocols/meson.build
new file mode 100644
index 00000000..73a6fda5
--- /dev/null
+++ b/protocols/meson.build
@@ -0,0 +1,49 @@
+wl_protocol_dir = wayland_protos.get_pkgconfig_variable('pkgdatadir')
+
+wayland_scanner = find_program('wayland-scanner')
+
+wayland_scanner_server = generator(
+	wayland_scanner,
+	output: '@BASENAME@-protocol.h',
+	arguments: ['server-header', '@INPUT@', '@OUTPUT@'],
+)
+
+wayland_scanner_code = generator(
+	wayland_scanner,
+	output: '@BASENAME@-protocol.c',
+	arguments: ['code', '@INPUT@', '@OUTPUT@'],
+)
+
+wayland_scanner_client = generator(
+	wayland_scanner,
+	output: '@BASENAME@-client-protocol.h',
+	arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
+)
+
+protocols = []
+
+client_protocols = [
+	'wlr-layer-shell-unstable-v1.xml',
+]
+
+wl_protos_src = []
+wl_protos_headers = []
+
+foreach p : protocols
+	xml = join_paths(p)
+	wl_protos_src += wayland_scanner_code.process(xml)
+	wl_protos_headers += wayland_scanner_server.process(xml)
+endforeach
+
+foreach p : client_protocols
+	xml = join_paths(p)
+	wl_protos_headers += wayland_scanner_client.process(xml)
+endforeach
+
+lib_wl_protos = static_library('wl_protos', wl_protos_src + wl_protos_headers,
+	dependencies: [wayland_client]) # for the include directory
+
+sway_protos = declare_dependency(
+	link_with: lib_wl_protos,
+	sources: wl_protos_headers,
+)
-- 
cgit v1.2.3