From d08cc85fc1f7beba59ec74bd1f2d8a804183ce2d Mon Sep 17 00:00:00 2001
From: Aylur <k.demeter@protonmail.com>
Date: Sun, 1 Sep 2024 02:48:34 +0200
Subject: move to monorepo

---
 notifd/src/meson.build | 79 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)
 create mode 100644 notifd/src/meson.build

(limited to 'notifd/src/meson.build')

diff --git a/notifd/src/meson.build b/notifd/src/meson.build
new file mode 100644
index 0000000..d3efa36
--- /dev/null
+++ b/notifd/src/meson.build
@@ -0,0 +1,79 @@
+version_split = meson.project_version().split('.')
+api_version = version_split[0] + '.' + version_split[1]
+gir = 'AstalNotifd-' + api_version + '.gir'
+typelib = 'AstalNotifd-' + api_version + '.typelib'
+
+config = configure_file(
+  input: 'config.vala.in',
+  output: 'config.vala',
+  configuration: {
+    'VERSION': meson.project_version(),
+    'MAJOR_VERSION': version_split[0],
+    'MINOR_VERSION': version_split[1],
+    'MICRO_VERSION': version_split[2],
+  },
+)
+
+deps = [
+  dependency('glib-2.0'),
+  dependency('gobject-2.0'),
+  dependency('gio-2.0'),
+  dependency('json-glib-1.0'),
+  dependency('gdk-pixbuf-2.0'),
+]
+
+sources = [
+  config,
+  'daemon.vala',
+  'notifd.vala',
+  'notification.vala',
+  'proxy.vala',
+]
+
+if get_option('lib')
+  lib = library(
+    meson.project_name(),
+    sources,
+    dependencies: deps,
+    vala_header: meson.project_name() + '.h',
+    vala_vapi: meson.project_name() + '-' + api_version + '.vapi',
+    vala_gir: gir,
+    version: meson.project_version(),
+    install: true,
+    install_dir: [true, true, true, true],
+  )
+
+  import('pkgconfig').generate(
+    lib,
+    name: meson.project_name(),
+    filebase: meson.project_name() + '-' + api_version,
+    version: meson.project_version(),
+    subdirs: meson.project_name(),
+    requires: deps,
+    install_dir: get_option('libdir') / 'pkgconfig',
+  )
+
+  custom_target(
+    typelib,
+    command: [
+      find_program('g-ir-compiler'),
+      '--output', '@OUTPUT@',
+      '--shared-library', get_option('prefix') / get_option('libdir') / '@PLAINNAME@',
+      meson.current_build_dir() / gir,
+    ],
+    input: lib,
+    output: typelib,
+    depends: lib,
+    install: true,
+    install_dir: get_option('libdir') / 'girepository-1.0',
+  )
+endif
+
+if get_option('cli')
+  executable(
+    meson.project_name(),
+    ['cli.vala', sources],
+    dependencies: deps,
+    install: true,
+  )
+endif
-- 
cgit v1.2.3