From 6a8c41cd1d5e218d0dacffb836fdd7d4ec6333dd Mon Sep 17 00:00:00 2001
From: Aylur <k.demeter@protonmail.com>
Date: Mon, 14 Oct 2024 16:01:36 +0000
Subject: feat: astal-io

---
 lib/astal/io/meson.build | 90 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 lib/astal/io/meson.build

(limited to 'lib/astal/io/meson.build')

diff --git a/lib/astal/io/meson.build b/lib/astal/io/meson.build
new file mode 100644
index 0000000..426a6d6
--- /dev/null
+++ b/lib/astal/io/meson.build
@@ -0,0 +1,90 @@
+project(
+  'astal-io',
+  'vala',
+  'c',
+  version: run_command('cat', join_paths(meson.project_source_root(), 'version')).stdout().strip(),
+  meson_version: '>= 0.62.0',
+  default_options: [
+    'warning_level=2',
+    'werror=false',
+    'c_std=gnu11',
+  ],
+)
+
+version_split = meson.project_version().split('.')
+api_version = version_split[0] + '.' + version_split[1]
+gir = 'AstalIO-' + api_version + '.gir'
+typelib = 'AstalIO-' + api_version + '.typelib'
+libdir = get_option('prefix') / get_option('libdir')
+pkgdatadir = get_option('prefix') / get_option('datadir') / 'astal'
+
+config = configure_file(
+  input: 'config.vala.in',
+  output: 'config.vala',
+  configuration: {
+    'VERSION': meson.project_version(),
+    'MAJOR_VERSION': version_split[0],
+    'MINOR_VERSION': version_split[1],
+    'MICRO_VERSION': version_split[2],
+  },
+)
+
+deps = [
+  dependency('glib-2.0'),
+  dependency('gio-unix-2.0'),
+  dependency('gobject-2.0'),
+  dependency('gio-2.0'),
+]
+
+sources = [
+  config,
+  'application.vala',
+  'file.vala',
+  'process.vala',
+  'time.vala',
+  'variable.vala',
+]
+
+lib = library(
+  meson.project_name(),
+  sources,
+  dependencies: deps,
+  vala_header: meson.project_name() + '.h',
+  vala_vapi: meson.project_name() + '-' + api_version + '.vapi',
+  vala_gir: gir,
+  version: meson.project_version(),
+  install: true,
+  install_dir: [true, true, true, true],
+)
+
+import('pkgconfig').generate(
+  lib,
+  name: meson.project_name(),
+  filebase: meson.project_name() + '-' + api_version,
+  version: meson.project_version(),
+  subdirs: meson.project_name(),
+  requires: deps,
+  install_dir: libdir / 'pkgconfig',
+)
+
+custom_target(
+  typelib,
+  command: [
+    find_program('g-ir-compiler'),
+    '--output', '@OUTPUT@',
+    '--shared-library', libdir / '@PLAINNAME@',
+    meson.current_build_dir() / gir,
+  ],
+  input: lib,
+  output: typelib,
+  depends: lib,
+  install: true,
+  install_dir: libdir / 'girepository-1.0',
+)
+
+executable(
+  'astal',
+  ['cli.vala', sources],
+  dependencies: deps,
+  install: true,
+)
-- 
cgit v1.2.3


From 306e64998c1bf1fb997c1098ae92d6edfef31cd2 Mon Sep 17 00:00:00 2001
From: Aylur <k.demeter@protonmail.com>
Date: Wed, 23 Oct 2024 20:37:32 +0000
Subject: docs: astal3 and io comments

---
 lib/astal/io/meson.build | 48 ++++++++++++++++++++++++++++++++----------------
 1 file changed, 32 insertions(+), 16 deletions(-)

(limited to 'lib/astal/io/meson.build')

diff --git a/lib/astal/io/meson.build b/lib/astal/io/meson.build
index 426a6d6..023dece 100644
--- a/lib/astal/io/meson.build
+++ b/lib/astal/io/meson.build
@@ -36,35 +36,41 @@ deps = [
   dependency('gio-2.0'),
 ]
 
-sources = [
-  config,
+sources = [config] + files(
   'application.vala',
   'file.vala',
   'process.vala',
   'time.vala',
   'variable.vala',
-]
+)
 
 lib = library(
   meson.project_name(),
   sources,
   dependencies: deps,
+  vala_args: ['--vapi-comments'],
   vala_header: meson.project_name() + '.h',
   vala_vapi: meson.project_name() + '-' + api_version + '.vapi',
-  vala_gir: gir,
   version: meson.project_version(),
   install: true,
-  install_dir: [true, true, true, true],
+  install_dir: [true, true, true],
 )
 
-import('pkgconfig').generate(
-  lib,
-  name: meson.project_name(),
-  filebase: meson.project_name() + '-' + api_version,
-  version: meson.project_version(),
-  subdirs: meson.project_name(),
-  requires: deps,
-  install_dir: libdir / 'pkgconfig',
+pkgs = []
+foreach dep : deps
+  pkgs += ['--pkg=' + dep.name()]
+endforeach
+
+gir_tgt = custom_target(
+  gir,
+  command: [find_program('python3'), files('gir.py'), meson.project_name(), gir]
+  + pkgs
+  + sources,
+  input: sources,
+  depends: lib,
+  output: gir,
+  install: true,
+  install_dir: get_option('datadir') / 'gir-1.0',
 )
 
 custom_target(
@@ -72,14 +78,24 @@ custom_target(
   command: [
     find_program('g-ir-compiler'),
     '--output', '@OUTPUT@',
-    '--shared-library', libdir / '@PLAINNAME@',
+    '--shared-library', get_option('prefix') / get_option('libdir') / '@PLAINNAME@',
     meson.current_build_dir() / gir,
   ],
   input: lib,
   output: typelib,
-  depends: lib,
+  depends: [lib, gir_tgt],
   install: true,
-  install_dir: libdir / 'girepository-1.0',
+  install_dir: get_option('libdir') / 'girepository-1.0',
+)
+
+import('pkgconfig').generate(
+  lib,
+  name: meson.project_name(),
+  filebase: meson.project_name() + '-' + api_version,
+  version: meson.project_version(),
+  subdirs: meson.project_name(),
+  requires: deps,
+  install_dir: get_option('libdir') / 'pkgconfig',
 )
 
 executable(
-- 
cgit v1.2.3