From 9fab13452a26ed55c01047d4225f699f43bba20d Mon Sep 17 00:00:00 2001
From: Aylur <k.demeter@protonmail.com>
Date: Mon, 14 Oct 2024 16:45:03 +0000
Subject: feat: Astal3

---
 lib/astal/gtk3/src/widget/box.vala | 50 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 lib/astal/gtk3/src/widget/box.vala

(limited to 'lib/astal/gtk3/src/widget/box.vala')

diff --git a/lib/astal/gtk3/src/widget/box.vala b/lib/astal/gtk3/src/widget/box.vala
new file mode 100644
index 0000000..d23a799
--- /dev/null
+++ b/lib/astal/gtk3/src/widget/box.vala
@@ -0,0 +1,50 @@
+public class Astal.Box : Gtk.Box {
+    [CCode (notify = false)]
+    public bool vertical {
+        get { return orientation == Gtk.Orientation.VERTICAL; }
+        set { orientation = value ? Gtk.Orientation.VERTICAL : Gtk.Orientation.HORIZONTAL; }
+    }
+
+    public List<weak Gtk.Widget> children {
+        set { _set_children(value); }
+        owned get { return get_children(); }
+    }
+
+    public new Gtk.Widget child {
+        owned get { return _get_child(); }
+        set { _set_child(value); }
+    }
+
+    construct {
+        notify["orientation"].connect(() => {
+            notify_property("vertical");
+        });
+    }
+
+    private void _set_child(Gtk.Widget child) {
+        var list = new List<weak Gtk.Widget>();
+        list.append(child);
+        _set_children(list);
+    }
+
+    private Gtk.Widget? _get_child() {
+        foreach(var child in get_children())
+            return child;
+
+        return null;
+    }
+
+    private void _set_children(List<weak Gtk.Widget> arr) {
+        foreach(var child in get_children()) {
+            remove(child);
+        }
+
+        foreach(var child in arr)
+            add(child);
+    }
+
+    public Box(bool vertical, List<weak Gtk.Widget> children) {
+        this.vertical = vertical;
+        _set_children(children);
+    }
+}
-- 
cgit v1.2.3