From c5342a93cc98569695474c692ef40f1e851c2912 Mon Sep 17 00:00:00 2001
From: Aylur <k.demeter@protonmail.com>
Date: Sun, 1 Sep 2024 03:19:54 +0200
Subject: move to monorepo

---
 bluetooth/src/meson.build | 66 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 bluetooth/src/meson.build

(limited to 'bluetooth/src/meson.build')

diff --git a/bluetooth/src/meson.build b/bluetooth/src/meson.build
new file mode 100644
index 0000000..cbc38ce
--- /dev/null
+++ b/bluetooth/src/meson.build
@@ -0,0 +1,66 @@
+version_split = meson.project_version().split('.')
+api_version = version_split[0] + '.' + version_split[1]
+gir = 'AstalBluetooth-' + api_version + '.gir'
+typelib = 'AstalBluetooth-' + api_version + '.typelib'
+
+config = configure_file(
+  input: 'config.vala.in',
+  output: 'config.vala',
+  configuration: {
+    'VERSION': meson.project_version(),
+    'MAJOR_VERSION': version_split[0],
+    'MINOR_VERSION': version_split[1],
+    'MICRO_VERSION': version_split[2],
+  },
+)
+
+deps = [
+  dependency('glib-2.0'),
+  dependency('gobject-2.0'),
+  dependency('gio-2.0'),
+]
+
+sources = [
+  config,
+  'utils.vala',
+  'device.vala',
+  'adapter.vala',
+  'bluetooth.vala',
+]
+
+lib = library(
+  meson.project_name(),
+  sources,
+  dependencies: deps,
+  vala_header: meson.project_name() + '.h',
+  vala_vapi: meson.project_name() + '-' + api_version + '.vapi',
+  vala_gir: gir,
+  version: meson.project_version(),
+  install: true,
+  install_dir: [true, true, true, true],
+)
+
+import('pkgconfig').generate(
+  lib,
+  name: meson.project_name(),
+  filebase: meson.project_name() + '-' + api_version,
+  version: meson.project_version(),
+  subdirs: meson.project_name(),
+  requires: deps,
+  install_dir: get_option('libdir') / 'pkgconfig',
+)
+
+custom_target(
+  typelib,
+  command: [
+    find_program('g-ir-compiler'),
+    '--output', '@OUTPUT@',
+    '--shared-library', get_option('prefix') / get_option('libdir') / '@PLAINNAME@',
+    meson.current_build_dir() / gir,
+  ],
+  input: lib,
+  output: typelib,
+  depends: lib,
+  install: true,
+  install_dir: get_option('libdir') / 'girepository-1.0',
+)
-- 
cgit v1.2.3